Is there a way to....

[Sirex]

Try this J

@echo off
for %%a in (*.mkv) do (
    echo Found %%a
    echo - Making DIR %%~na
    mkdir "%%~na"
    echo - Moving %%~na.* to %%~na
    move "%%~na.*" "%%~na"
)
pause

change *.mkv for any ext you like
ie
*.mkv;*.avi
*.mkv;*.avi;*.divx

it will move like named files into the same dir
so if you have
Iron_Man_3.mkv
Iron_Man_3.srt
it will move them together..


if you want to change _ to spaces from the dir try this

@echo off
setlocal enabledelayedexpansion
for %%a in (*.mkv) do (
    echo Found %%a
    echo - Making DIR %%~na
    mkdir "%%~na"
    echo - Moving %%~na.* to %%~na
    move "%%~na.*" "%%~na"
    set foldername=%%~na
    echo - Renaming DIR to "!foldername:_= !"
    ren "!foldername!" "!foldername:_= !"
)
pause

This one will rename the files inside the folder too... hopefully

@echo off
setlocal enabledelayedexpansion
for %%a in (*.mkv) do (
    echo Found %%a
    echo - Making DIR %%~na
    mkdir "%%~na"
    echo - Moving %%~na.* to %%~na
    move "%%~na.*" "%%~na"
    set foldername=%%~na
    echo - Renaming DIR to "!foldername:_= !"
    ren "!foldername!" "!foldername:_= !"
    cd "!foldername:_= !"
    for %%b in (*) do (
    	set filename=%%b
        echo - Renaming file "!filename!" to "!filename:_= !"
    	ren "!filename!" "!filename:_= !"
    )
    cd ..
)
pause

Dun ask me where I keep all this info... I dunno where its all stored lmao

[juneau]

Thanks for those Sirex! What changes do I have to make to them if I don't want - or _? My file names with multiple words simply have spaces, and so do the folder names.

[Sirex]

Use the first one, it does no stripping.
Simple as that

[juneau]

Use the first one, it does no stripping.
Simple as that

Will give it a test run this weekend. Thanks!